Internet Radio » FabLab Radio

#include <Bridge.h>

#include <YunServer.h>

#include <YunClient.h>

#include <Process.h>

#include <TFT.h>  // Arduino LCD library

#include <SPI.h>

#define cs   10

#define dc   9

#define rst  8

/* Rotary encoder read */

#define ENC_A 3

#define ENC_B 2

#define ENC_PORT PIND

/* Play Stop Button */

#define PLAY 7

#define NCH 16

TFT tft = TFT(cs, dc, rst);

char chPrint[3] = {'0', '1', '\0'};

char chanPrint[20];

char namePrint[80];

char genrePrint[40];

char titlePrint[80];

String nameString, genreString, titleString;

unsigned long lastChange;

unsigned long now, nextEnc, nextCli, nextScr;

unsigned char chn = 1;

boolean playState;

boolean playPressed;

String chnStr;

String channelStr[16] = {

  String("01"), String("02"), String("03"), String("04"),

  String("05"), String("06"), String("07"), String("08"),

  String("09"), String("10"), String("11"), String("12"),

  String("13"), String("14"), String("15"), String("16")};

String chStr[16] = {

  String("01"), String("02"), String("03"), String("04"),

  String("05"), String("06"), String("07"), String("08"),

  String("09"), String("10"), String("11"), String("12"),

  String("13"), String("14"), String("15"), String("16")};

// Listen on default port 5555, the webserver on the Yun

// will forward there all the HTTP requests for us.

YunServer server;

void setup() {

  /* Setup encoder pins as inputs */

  pinMode(ENC_A, INPUT_PULLUP);

  //digitalWrite(ENC_A, HIGH);

  pinMode(ENC_B, INPUT_PULLUP);

  //digitalWrite(ENC_B, HIGH);

  pinMode(PLAY, INPUT_PULLUP);

  // Initialize Bridge

  Bridge.begin();

  server.listenOnLocalhost();

  server.begin();

  tft.begin();

  tft.background(0, 0, 0);

  tft.stroke(0, 0, 255);

  tft.setTextSize(2);

  tft.setTextWrap(true);

  tft.text("FabLab  Radio", 0, 0);

  chnStr = channelStr[0];

  chnStr.toCharArray(chanPrint, chnStr.length() + 1);

  tft.stroke(255, 255, 255);

  tft.text(chanPrint, 0, 20);

  tft.stroke(0, 0, 255);

  tft.text("Stop", 0, 110);

  tft.stroke(0, 255, 0);

  tft.text(chPrint, 130, 110);

  playState = false;

  playPressed = false;

  lastChange = millis();

  nextEnc = millis();

  nextCli = millis();

  nextScr = millis();

}

void loop() {

  static uint8_t counter = 0;      //this variable will be changed by encoder input

  int8_t tmpdata;

  static boolean bis = false;

  now = millis();

  if (now >= nextEnc) {

    nextEnc = now + 5;

    read_button();

    if (playPressed) {

        runRadio(chn);

    }

    tmpdata = read_encoder();

    if(tmpdata != 0) {

      bis = !bis;

      if (bis) {

        if ((millis() - lastChange) > 500) {

          chStr[chn - 1].toCharArray(chPrint, 3);

          tft.setTextSize(2);

          tft.stroke(0, 0, 0);

          tft.text(chPrint, 130, 110);

          counter += tmpdata;

          chn = counter % NCH + 1;

          chStr[chn - 1].toCharArray(chPrint, 3);

          tft.stroke(0, 255, 0);

          tft.text(chPrint, 130, 110);

          runRadio(chn);

          lastChange = millis();

        }

        //delay(10);

      }

    }

  }

  now = millis();

  if (now >= nextCli) {

    nextCli = now + 50;

    YunClient client = server.accept();

    if (client) {

      process(client);

      client.stop();

    }

  }

}

void runRadio(int n) {

  String ch =  String(n);

  String pl = playState ? "1" : "0";

  chnStr = channelStr[n - 1];

  tft.setTextSize(2);

  tft.stroke(0, 0, 0);

  tft.text(chanPrint, 0, 20);

  chnStr.toCharArray(chanPrint, chnStr.length() + 1);

  //tft.background(0, 0, 0);

  tft.stroke(255, 255, 255);

  tft.text(chanPrint, 0, 20);

  if (playState)

  {

    tft.stroke(0, 0, 0);

    tft.text("Stop", 0, 110);

    tft.stroke(0, 255, 0);

    tft.text("Play", 0, 110);

  }

  else

  {

    tft.stroke(0, 0, 0);

    tft.text("Play", 0, 110);

    tft.stroke(0, 0, 255);

    tft.text("Stop", 0, 110);

    tft.setTextSize(1);

    tft.stroke(0, 0, 0);

    tft.textWrap(namePrint, 0, 40);

    tft.textWrap(genrePrint, 0, 70);

    tft.textWrap(titlePrint, 0, 80);

  }

  Process p;

  p.begin("/root/radioyun1.sh");

  p.addParameter(ch);

  p.addParameter(pl);

  p.run();

}

void read_button()

{

  if (digitalRead(PLAY) == LOW && playPressed == false)

  {

    playPressed = true;

    playState = !playState;

  }

  else if (playPressed == true && digitalRead(PLAY) == HIGH)

  {

    playPressed = false;

  }

}

/* returns change in encoder state (-1,0,1) */

int8_t read_encoder()

{

  static int8_t enc_states[] = {0,-1,1,0,1,0,0,-1,-1,0,0,1,0,1,-1,0};

  static uint8_t old_AB = 0;

  old_AB <<= 2;                   //remember previous state

  old_AB |= ( ENC_PORT & 0x03 );  //add current state

  return ( enc_states[( old_AB & 0x0f )]);

}

void process(YunClient client) {

  // read the command

  String command = client.readStringUntil('/');

  if (command == "name") {

    nameCommand(client);

  } else if (command == "genre") {

    genreCommand(client);

  } else if (command == "title") {

    titleCommand(client);

  } else if (command == "chname") {

    chnameCommand(client);

  }

}

void nameCommand(YunClient client) {

  nameString = client.readStringUntil('/');

  // Send to the Screen

  if (playState)

  {

    tft.setTextSize(1);

    tft.stroke(0, 0, 0);

    tft.textWrap(namePrint, 0, 40);

    int msgLen = nameString.length();

    if (msgLen < 78)

      nameString.toCharArray(namePrint, msgLen);

    else

      nameString.toCharArray(namePrint, 78);

    //tft.background(0, 0, 0);

    tft.stroke(255, 127, 63);

    tft.textWrap(namePrint, 0, 40);

  }

}

void genreCommand(YunClient client) {

  genreString = client.readStringUntil('/');

  // Send to the Screen

  if (playState)

  {

    tft.setTextSize(1);

    tft.stroke(0, 0, 0);

    tft.textWrap(genrePrint, 0, 70);

    int msgLen = genreString.length();

    if (msgLen < 40)

      genreString.toCharArray(genrePrint, genreString.length());

    else

      genreString.toCharArray(genrePrint, 40);

    //tft.background(0, 0, 0);

    tft.stroke(127, 255, 63);

    tft.textWrap(genrePrint, 0, 70);

  }

}

void titleCommand(YunClient client) {

  titleString = client.readStringUntil('/');

  // Send to the Screen

  if (playState)

  {

    tft.setTextSize(1);

    tft.stroke(0, 0, 0);

    tft.textWrap(titlePrint, 0, 80);

    int msgLen = titleString.length();

    if (msgLen < 78)

      titleString.toCharArray(titlePrint, titleString.length());

    else

      titleString.toCharArray(titlePrint, 78);

    //tft.background(0, 0, 0);

    tft.stroke(63, 127, 255);

    tft.textWrap(titlePrint, 0, 80);

  }

}

void chnameCommand(YunClient client) {

  String message = client.readStringUntil('/');

  int numch = client.parseInt();

  channelStr[numch - 1] = message;  

}